package net.yaimo.sound
{
	import flash.events.Event;
	import flash.media.Sound;
	import flash.media.SoundChannel;
	import flash.media.SoundTransform;
	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.core.easing.EaseNone;
	import org.libspark.betweenas3.core.easing.IEasing;
	import org.libspark.betweenas3.easing.*;
	import org.libspark.betweenas3.events.TweenEvent;
	import org.libspark.betweenas3.tweens.ITween;
 
	/**
	 * @author yaimo(yaimo.net)
	 * BetweenAS3依存のSingletonのSoundManagerクラスです。
	 * 一度初期化を行うことにより、SoundManagerをimportすることにより、どこでも使用することができます。
	 *
	 * @example
	 * import SoundManager
	 *
	 * //Soundの初期化
	 * SoundManager.instance.init(new BGM(), new ClickSound(), new OverSound());
	 *
	 * //BGMのコントロール
	 * SoundManager.instance.setBgmVol(0.8);//初期ボリュームの設定
	 * SoundManager.instance.playBGM();//再生
	 * SoundManager.instance.setBgmVol(0.2);//ボリュームの変更
	 * SoundManager.instance.stopBGM();//停止
	 *
	 * //ボタン音の再生
	 * SoundManager.instance.playBtnOverSound();
	 * SoundManager.instance.playBtnClickSound();
	 * SoundManager.instance.btnMute = false;//ボタン音のミュート設定
	 */
 
	//将来的な機能memo
	//TODO 最大音量と最少音量設定にする@2009/09/01 21:16 - yaimo
	//TODO 全体のボリュームもコントロールできるようにできたらいい? @2009/09/03 18:01 - yaimo
	//TODO 将来的にsetBGM=0にしたときに自動でstop,playするかの機能？ @2009/09/03 18:28 - yaimo
	//TODO stopTween終了、playTween終了後の関数を登録できるようにする @2009/09/06 2:31 - yaimo
 
	public class SoundManager
	{
		/*** Tween関連 ***/
		private var iTween:ITween;
		private var remainderTime:Number;
 
		/*======================================================================*//**
		 *
 
BGMを設定、取得します。
 
		 */
		public function get bgm():Sound { return _bgm; }
		public function set bgm(value:Sound):void {_bgm = value;}
		private	var _bgm:Sound;
 
		/*======================================================================*//**
		 *
 
BGMが再生している場合、BGMのSoundChannelプロパティを取得します。
 
		 */
		public function get bgmChannel():SoundChannel { return _bgmChannel; }
		private	var _bgmChannel:SoundChannel;
 
		/*======================================================================*//**
		 *
 
Click音を設定、取得します。
 
		 */
		public function get btnClick():Sound { return _btnClick; }
		public function set btnClick(value:Sound):void {_btnClick = value;}
		private	var _btnClick:Sound;
 
		/*======================================================================*//**
		 *
 
Over音を設定、取得します。
 
		 */
		public function get btnOver():Sound { return _btnOver; }
		public function set btnOver(value:Sound):void { _btnOver = value; }
		private	var _btnOver:Sound;
 
		/*======================================================================*//**
		 *
 
ボタンのミュート状態を設定、取得します。
 
		 */
		public function get btnMute():Boolean { return _btnMute; }
		public function set btnMute(value:Boolean):void { _btnMute = value; }
		private var _btnMute:Boolean;
 
		/*======================================================================*//**
		 *
 
BGMをloopするかどうかを設定、取得します。
 
		 */
		public function get loop():Boolean { return _loop; }
		public function set loop(value:Boolean):void {_loop = value;}
		private var _loop:Boolean = true;
 
		/*======================================================================*//**
		 *
 
BGM再生後のボリュームを取得します。
 
		 */
		public function get nextBgmVol():Number { return _nextBgmVol; }
		private	var _nextBgmVol:Number = 1;
 
		/*======================================================================*//**
		 *
 
BGM再生中のボリュームを取得します。
 
		 */
 
		public function get bgmVol():Number { return _bgmChannel.soundTransform.volume; }
 
		/*======================================================================*//**
		 *
 
BGMが再生中かどうかをBoolean型で取得します。
 
		 */
		public function get isPlayingBGM():Boolean { return _isPlayingBGM; }
		private var _isPlayingBGM:Boolean;
 
		/*======================================================================*//**
		 *
 
BGMを停止した位置を取得します。
 
		 */
		public function get stopPosition():Number { return _stopPosition; }
		private var _stopPosition:Number = 0;
 
		/*======================================================================*//**
		 *
 
Tween中かどうかをBooleanで取得します。
 
		 */
		public function get isTween():Boolean { return _isTween; }
		private var _isTween:Boolean;
 
		/*======================================================================*//**
		 *
 
stopBGMのTween中かどうかをBooleanで取得します。
 
		 */
		public function get isStopTween():Boolean { return _isStopTween; }
		private var _isStopTween:Boolean;
 
		/*======================================================================*//**
		 *
 
Tweenに使用するEasingを設定します。
 
		 */
		public function get easing():IEasing { return _easing; }
		public function set easing(value:IEasing):void {_easing = value;}
		private var _easing:IEasing;
 
		/*======================================================================*//**
		 *
 
すべてのメソッド、プロパティにアクセスするためのSoundManagerインスタンス
 
		 */
		static private var _instance:SoundManager = new SoundManager();
        static public function get instance():SoundManager { return _instance; }
 
		/*======================================================================*//**
		 *
 
SoundManagerはインスタンスできません。
 
		 */
		public function SoundManager() { if (_instance) throw new ArgumentError("Singleton クラスは外部からインスタンス化できません."); }
 
		/**
		 * @param BGMを指定
		 * @param Click音を指定
		 * @param Over音を指定
		 * @example
		 * SoundManager.instance.init(new BGM(), new ClickSound(), new OverSound());
		 */
		public function init(bgm:Sound=null,btnClick:Sound=null,btnOver:Sound=null):void{
			this.bgm = bgm;
			this.btnClick = btnClick;
			this.btnOver = btnOver;
		}
		//--------------------------------------------------------------------------
		//
		// BtnSound
		//
		//--------------------------------------------------------------------------
		/**
		 * play RollOver sound
		 */
		public function playBtnOverSound():void{
			if (_btnMute) return;
			if (btnOver) btnOver.play();
		}
 
		/**
		 * play Click sound
		 */
		public function playBtnClickSound():void {
			if (_btnMute) return;
			if (btnClick) btnClick.play();
		}
 
		//--------------------------------------------------------------------------
		//
		// BgmSound
		//
		//--------------------------------------------------------------------------
		/**
		 * Play BGM
		 * @param 	startPosition		再生位置(ミリ秒)
		 * @param 	tween		ボリューム0からTween再生するかどうかをBoolean型で設定
		 * @param	tweenTime 		Tween時間(秒)
		 * @example
		 * SoundManager.instance.playBGM();//再生
		 * SoundManager.instance.playBGM(0,true);//ボリューム0からTweenしながら再生
		 * SoundManager.instance.playBGM(SoundManager.instance.stopPosition);//停止位置からの再生
		 */
		public function playBGM(startPosition:Number = 0, tween:Boolean = false, tweenTime:Number = 1 ):void {
 
			if (_isPlayingBGM) return;
			_isPlayingBGM = true;
 
			/*** stopTweenの中断処理 ***/
			if (_isStopTween) _isStopTween = false;
			else {
				_bgmChannel = bgm.play(startPosition);//BGMの再生
				if (_loop) _bgmChannel.addEventListener(Event.SOUND_COMPLETE, BGMLoopHandler);//BGMのループ処理をする場合
			}
			/*** ボリューム処理 ***/
			if (tween) setTweenVolume(_nextBgmVol, 0, tweenTime);
			else setVolume(_nextBgmVol);
		}
 
		/**
		 * BGMのループ処理関数
		 */
		private function BGMLoopHandler(e:Event):void {
 
			var currentVol:Number = bgmVol; //現在のボリュームを次のボリュームに引き継ぐ
			/*** bgmのループ再生処理 ***/
			_bgmChannel.removeEventListener(Event.SOUND_COMPLETE, BGMLoopHandler);
			_bgmChannel = null;
			_bgmChannel = bgm.play();
			_bgmChannel.addEventListener(Event.SOUND_COMPLETE, BGMLoopHandler);
 
			/*** ボリューム処理 ***/
			if (_isTween) {
				remainderTime	= int((remainderTime - iTween.position) * 10) / 10;//小数点第一まで減らす。
 
				if (_isStopTween) setTweenVolume(0, currentVol, remainderTime );
				else setTweenVolume(_nextBgmVol, currentVol, remainderTime);
			}
			else setVolume(currentVol);
		}
 
		/**
		 * BGMのストップ処理(すでにstop中だったら無視
		 * @param 	tween		ボリューム0にTween再生するかどうかをBoolean型で設定
		 * @param 	tweenTime		Tween時間(秒)
		 * @example
		 * SoundManager.instance.stopBGM();//再生
		 * SoundManager.instance.stopBGM(true);//ボリューム0にTweenしながら停止
		 */
		public function stopBGM(tween:Boolean = false, tweenTime:Number = 1 ):void {
 
			if (!_isPlayingBGM) return;
			_isPlayingBGM = false;
 
			/*** ボリューム処理 ***/
			if (tween) {
				if (_isStopTween) return;
				_isStopTween = true;
				setTweenVolume(0, bgmVol, tweenTime );
			}
			else {
				removeTween();
				stopFunc();
			}
		}
 
		/**
		 * BGMをstop()させる際の処理をまとめた関数
		 */
		private function stopFunc():void {
 
			/*** 再生をstopした場所を保持 ***/
			_stopPosition = _bgmChannel.position;
			_bgmChannel.stop();
 
			/*** 状態の変更 ***/
			_isStopTween = false;
 
			/*** BGMのループ処理が登録されている場合 ***/
			if (_bgmChannel.hasEventListener(Event.SOUND_COMPLETE)) _bgmChannel.removeEventListener(Event.SOUND_COMPLETE, BGMLoopHandler);
			_bgmChannel = null;
		};
 
		/**
		 * Bgmのボリューム変更
		 * @param 	volume		変更するボリュームを指定
		 * @param 	tween		Tweenでのボリューム変更するかどうかをBoolean型で設定
		 * @param 	tweenTime		Tweenさせる時間を指定
		 * @param
		 * SoundManager.instance.setBgmVol(0.5);//ボリュームを0.5に変更
		 *	SoundManager.instance.setBgmVol(0.5,true);//ボリューム0.5にTween処理しながら変更
		 */
		public function setBgmVol(volume:Number,tween:Boolean=false,tweenTime:Number=1):void {
 
			/*** ボリュームの保持***/
			_nextBgmVol = volume;
 
			if (_isPlayingBGM) {
				/*** stopTweenの中断処理 ***/
				if (_isStopTween) _isStopTween = false;
				/*** ボリューム処理 ***/
				if (tween) setTweenVolume(volume, bgmVol, tweenTime);
				else setVolume(volume);
			}
		}
 
		//--------------------------------------------------------------------------
		//
		// VolumeController
		//
		//--------------------------------------------------------------------------
		/**
		 * Tween"なし"でのボリューム設定
		 */
		private function setVolume(volume:Number):void {
 
			/*** Tween初期化 ***/
			removeTween();
 
			/*** ボリュームをセット ***/
			var soundTransform:SoundTransform = _bgmChannel.soundTransform;
			soundTransform.volume = volume;
			_bgmChannel.soundTransform = soundTransform;
			soundTransform = null;
		}
 
		/**
		 * Tween"あり"でのボリューム設定
		 */
		private function setTweenVolume(toVol:Number, fromVol:Number, tweenTime:Number = 1):void{
 
			/*** Tween初期化 ***/
			removeTween();
 
			/*** Tween作成 ***/
			iTween = BetweenAS3.tween(_bgmChannel, { soundTransform: { volume: toVol }}, { soundTransform: { volume: fromVol }}, tweenTime,_easing );
 
			/*** 開始関数 ***/
			iTween.onPlay = function ():void {
				_isTween = true;
				remainderTime = tweenTime;//残り時間の初期化
			}
			/*** 終了関数 ***/
			iTween.onComplete = function ():void {
				_isTween = false;
				iTween = null;
				if (_isStopTween) stopFunc();//ストップのtweenだったらstopする。
			}
			/*** Tween開始 ***/
			iTween.play();
		}
 
		/**
		 * Tween最中だった場合、Tweenを止めて削除する関数
		 */
		private function removeTween():void {
			if (!_isTween) return;
			else {
				iTween.stop();
				_isTween = false;
				iTween = null;
			}
		}
	}
}

var sList:SerialList = new SerialList();
			sList.id = "sList";
			sList.addCommand(
				//[		
				new Trace("SerialList.addCommand内でのthis.id: " + this.id),
				new Func(function ():void 
				{
					trace("SerialList.addCommand内でのthis" + this);
					trace("SerialList.addCommand内でのthis.parent" + this.parent);
					this.id = "Function";
					trace("SerialList.addCommand内でのthis.id: " + this.id);
				}),
				function ():void 
				{
					trace("SerialList.addCommand内でのthis.parent" + this.parent.id);
					this.parent.insertCommand(new Trace("追加1"));
					insertCommand(new Trace("追加2"));
				},
 
				[//ここからParallelList
				new Func(function ():void 
				{
					trace("SerialList.addCommand内でのthis: " + this);
					trace("SerialList.addCommand内でのthis.parent" + this.parent);
				}),
				],

private function hoge():void
		{
			var target:MovieClip = new MovieClip();
			trace("普通の関数内でのthis.id: "+this.id);
 
			target.addEventListener(MouseEvent.MOUSE_OUT,function ():void
			{
				trace("無名関数内でのtarget: "+target);
				trace("単純にthis: " + this);
				trace("ではthis.parent: " + this.parent);
				trace("無名関数内でのthis.id: " + this.id);
				trace("無名関数内でのthis.target: " + this.target);
				this.id = "this.idは無名関数内のidとして登録されています。";
				trace("登録後のthis: "+this.id);
			});

package 
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.TimerEvent;
	import flash.geom.ColorTransform;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.net.URLRequest;
	import flash.utils.Timer;
 
	[SWF(width="640", height="512", backgroundColor="0xFFFFFF", frameRate="24")]
 
	public class Main extends Sprite 
	{
 
		public static const SEGMENT_W:int = 10;
		public static const SEGMENT_H:int = 10;
		private var imageArray:Array = [];
		private var limegelocArray:Array = [];
		private var currentPosX:Array = []
		private var currentPosY:Array = []
		private var flag:Boolean;
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			var loader:Loader = new Loader();
			loader.load(new URLRequest("hoge.jpg"));
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, imgLoadCompHander);
		}
 
		private function imgLoadCompHander(e:Event):void 
		{
			var target:Loader = e.target.loader as Loader;
			target.contentLoaderInfo.removeEventListener(Event.COMPLETE, imgLoadCompHander);
			splitImage(DisplayObject(target));
		}
 
		private function splitImage(target:DisplayObject):void
		{
			var displayObj:DisplayObject = target;
			var splitWidth:Number = displayObj.width / SEGMENT_W;
			var splitHeight:Number = displayObj.height / SEGMENT_H;
 
			var mat:Matrix = new Matrix();
			var color:ColorTransform = new ColorTransform();
			var clip:Rectangle = new Rectangle(0, 0, splitWidth, splitHeight);
 
			for (var i:int = 0; i < SEGMENT_W; i++) 
			{
				imageArray.push(new Array());
				limegelocArray.push(new Array());
				currentPosX.push(new Array());
				currentPosY.push(new Array());
 
				for (var j:int = 0; j < SEGMENT_H; j++) 
				{
					mat.tx = -i * splitWidth;
					mat.ty = -j * splitHeight;
 
					limegelocArray[i].push(new Point(-mat.tx, -mat.ty));
 
					var bmpData:BitmapData = new BitmapData(splitWidth,splitHeight,false);
 
					bmpData.draw(displayObj, mat, color, null, clip, false);
 
					var bitmap:Bitmap = new Bitmap(bmpData);
					bitmap.x = clip.x;
					bitmap.y = clip.y;
 
					imageArray[i].push(bitmap);
 
 
					currentPosX[i][j] = Math.random() * stage.stageWidth;
					currentPosY[i][j] = Math.random() * stage.stageHeight;
 
					addChild(imageArray[i][j]);
				}
 
			}
 
			addEventListener(Event.ENTER_FRAME, onFrameHandler);
			var timer:Timer = new Timer(2000);
			timer.start();
			timer.addEventListener(TimerEvent.TIMER, timerEventHandler);
 
		}
 
		private function timerEventHandler(e:TimerEvent):void 
		{
			flag = !flag;
			var i:int;
			var j: int;
 
			if (flag) {
				for (i= 0; i < SEGMENT_W; i++) 
				{
					for (j = 0; j < SEGMENT_H; j++) 
					{
						currentPosX[i][j] = limegelocArray[i][j].x;
						currentPosY[i][j] = limegelocArray[i][j].y;
					}
				}
 
			}
			else {
				for (i = 0; i < SEGMENT_W; i++) 
				{
					for (j = 0; j < SEGMENT_H; j++) 
					{
						currentPosX[i][j] = Math.random() * stage.stageWidth;
						currentPosY[i][j] = Math.random() * stage.stageHeight;
					}
				}
			}
		}
 
		private function onFrameHandler(e:Event):void 
		{
			for (var i: int = 0; i < SEGMENT_W; i++) 
			{
				for (var j: int = 0; j < SEGMENT_H; j++) 
				{
					imageArray[i][j].x += (currentPosX[i][j] - imageArray[i][j].x) * 0.3;
					imageArray[i][j].y += (currentPosY[i][j] - imageArray[i][j].y) * 0.3;
				}
			}
 
		}
 
	}
 
}

var matrix:Matrix = new Matrix();
var point:Point = new Point(50,50);
//x,y 10倍の拡大
matrix.scale(10,10);
//x,y 100の移動
matrix.translate(100,100);
//50*10  (+100考慮しない) = 500
trace(matrix.deltaTransformPoint(point));//500,500
//50*10 + 100 = 500
trace(matrix.TransformPoint(point));//600,600